class_name ShotSetup extends Node3D

signal finished(source: ShotSetup)

enum Phase {
	AIM,
	POWER_ADJUST,
	CURVE_ADJUST,
	DOWNSWING,
	SHOT,
	FINISHED,
}

const PITCH_MIN := deg_to_rad(-60.0)
const PITCH_MAX := deg_to_rad(-5.0)
const ZOOM_LENGTH := 0.1
const ZOOM_ELEVATION_RATIO := 0.3166

const ZOOM_MIN := 1.0
const ZOOM_MAX := 12.0

const ARROW_ACCELERATION := 8.0
const PLAYER_ACCELERATION := 2.0

const FREE_CAM_RETURN_TIME := 0.618
const BALL_RETURN_TIME := 0.618
const CAMERA_SNAP_TIME := 0.3

const WASTED_BALL_RETURN_DELAY := 3.5

## Shots above this threshold trigger a "big power" effect
const BIG_POWER_THRESHOLD := 0.7

## Amount of life lost when landing in water
const WATER_DAMAGE := 10.0

## In Driving Range mode, the ball can be retrieved in the shot phase.
@export var driving_range := false

## Initially-selected club
@export var initial_club: Club.Type = Club.Type.DRIVER

@export_category("Shot Parameters")
@export var base_power := 2.5
@export var base_curve := 0.0

@export_category("Debug")
## When enabled, the game will pause and enter free cam mode when the ball has a collision.
@export var debug_ball_impact := false
## When enabled, ignore curve meter and hit a perfect shot every time.
@export var perfect_aim := false
## Keep projection visible
@export var keep_projection := false

var player: WorldPlayer

var base_speed: float = ProjectSettings.get_setting("game/config/controls/camera/free_camera_speed")

var x_sensitivity: float = ProjectSettings.get_setting(
	"game/config/controls/camera/x_axis_sensitivity"
)
var x_acceleration: float = ProjectSettings.get_setting(
	"game/config/controls/camera/x_axis_acceleration"
)
var y_sensitivity: float = ProjectSettings.get_setting(
	"game/config/controls/camera/y_axis_sensitivity"
)
var y_acceleration: float = ProjectSettings.get_setting(
	"game/config/controls/camera/y_axis_acceleration"
)

var invert_pitch: bool = ProjectSettings.get_setting("game/config/controls/camera/invert_pitch")

var control_disabled := false

var phase: Phase = Phase.FINISHED:
	set(value):
		if value != phase:
			_on_phase_change(value)
		phase = value

var hud: ShotHUD:
	get:
		return world.ui.shot_hud if world and world.ui else null

var club: Club.Type:
	set(value):
		if value != club:
			_on_club_change(value)
		club = value

var shot_ref: Node3D

var shot_power: float:
	set(value):
		hud.power_bar.value = value
	get:
		return hud.power_bar.value

var shot_curve: float:
	set(value):
		hud.curve_bar.value = value
	get:
		return hud.power_bar.value

var _free_camera: FreeCamera
var _returning_free_camera := false
var _restart_queued := false

var _tracking_camera: OrbitalCamera

@onready var direction: Node3D = %Direction
@onready var elevation: Node3D = %Elevation
@onready var pitch: Node3D = %Pitch
@onready var zoom: Node3D = %Zoom
@onready var camera: Camera3D = %Camera

@onready var player_pivot: Node3D = %PlayerPivot
# TODO: genericize for selectable characters
@onready var character: CharacterController = $PlayerPivot/GfolfGirl

@onready var shot_animation: AnimationPlayer = %ShotAnimation

@onready var arrow: Node3D = %Arrow
@onready var arrow_pivot: Node3D = %ArrowPivot
@onready var arrow_animation: AnimationPlayer = %ArrowAnimation
@onready var shot_projection: ProjectileArc = %ShotProjection

@onready var ball_point: Node3D = %BallPoint
@onready var physics_ball: GameBall = %PhysicsBall

@onready var drive_ref: RayCast3D = %DriveRef
@onready var drive_arrow: Node3D = %DriveArrow
@onready var wedge_ref: RayCast3D = %WedgeRef
@onready var wedge_arrow: Node3D = %WedgeArrow
@onready var iron_ref: RayCast3D = %IronRef
@onready var iron_arrow: Node3D = %IronArrow
@onready var putt_ref: RayCast3D = %PuttRef
@onready var putt_arrow: Node3D = %PuttArrow

@onready var ball_return_timer: Timer = %BallReturnTimer

@onready var ball_impulse_debug: Node3D = %BallImpulseDebug

@onready var camera_distance := zoom.position.z:
	set = _set_camera_distance

@onready var phys_ball_scene := preload("res://src/equipment/balls/physics_ball/physics_ball.tscn")

@onready var world: World = get_tree().get_first_node_in_group(World.group)
@onready var game: Game = get_tree().get_first_node_in_group(Game.group)

@onready var _target_rotation := Vector2(pitch.rotation.x, direction.rotation.y)

static var scene := preload("res://src/player/shot_setup/shot_setup.tscn")


func _init_deferred() -> void:
	# Set up HUD
	club = initial_club


func _ready() -> void:
	_init_deferred.call_deferred()


func _set_camera_distance(value: float) -> void:
	var tween := get_tree().create_tween()
	tween.tween_property(zoom, "position:z", value, ZOOM_LENGTH).set_trans(Tween.TRANS_SINE)
	tween.set_parallel()
	(
		tween
		. tween_property(elevation, "position:y", value * ZOOM_ELEVATION_RATIO, ZOOM_LENGTH)
		. set_trans(Tween.TRANS_SINE)
	)
	camera_distance = value


func _unhandled_input(event: InputEvent) -> void:
	if event is InputEventMouseButton:
		Input.set_mouse_mode(Input.MOUSE_MODE_CAPTURED)
	elif event is InputEventMouseMotion:
		if Input.get_mouse_mode() == Input.MOUSE_MODE_CAPTURED:
			camera_motion((event as InputEventMouseMotion).relative)


func camera_motion(motion: Vector2) -> void:
	if not control_disabled and phase == Phase.AIM:
		# Can only control camera while aiming
		_target_rotation.y = _target_rotation.y - deg_to_rad(motion.x * x_sensitivity)
		_target_rotation.x = clampf(
			_target_rotation.x - deg_to_rad(motion.y * y_sensitivity) * (-1 if invert_pitch else 1),
			PITCH_MIN,
			PITCH_MAX
		)


## Return this instance to the AIM phase the next time we process while FINISHED.
func queue_restart() -> void:
	_restart_queued = true


func is_active() -> bool:
	return phase != Phase.FINISHED


func finish_downswing() -> void:
	phase = Phase.SHOT


func get_shot_impulse(meter_pct: float) -> Vector3:
	return -shot_ref.global_basis.z * base_power * meter_pct


func take_shot() -> void:
	# Impact screenshake & hitlag
	if game:
		if shot_power > BIG_POWER_THRESHOLD:
			game.viewport.hit_lag_big()
			var shake_intensity: float = (
				10.0 * (shot_power - BIG_POWER_THRESHOLD) / (1.0 - BIG_POWER_THRESHOLD)
			)
			game.viewport.screen_shake(shake_intensity, 1.0)
		else:
			game.viewport.hit_lag_small()

	print_debug("WHACK!\nPower: ", shot_power, "\nCurve: ", shot_curve)

	var impulse := get_shot_impulse(shot_power)
	print_debug("Shot impulse: ", impulse, "; ", impulse.length(), " N*s")

	ball_impulse_debug.transform = (
		Transform3D.IDENTITY.scaled(Vector3.ONE * impulse.length()).looking_at(impulse)
	)

	physics_ball.freeze = false
	physics_ball.apply_central_impulse(impulse)


## Make the shot projection widget visible, with animated transition
func _show_shot_projection() -> void:
	shot_projection.initial_speed = 1
	shot_projection.basis = shot_ref.basis.orthonormalized()
	var shot_speed := get_shot_impulse(1.0).length() / physics_ball.mass
	var tween := get_tree().create_tween()
	tween.tween_property(shot_projection, "initial_speed", shot_speed, CAMERA_SNAP_TIME).set_trans(
		Tween.TRANS_QUAD
	)
	shot_projection.show()


func insert_free_cam() -> void:
	arrow_animation.play("hide")
	_show_shot_projection()
	hud.hide_hud()
	_free_camera = FreeCamera.create(camera)
	add_sibling(_free_camera)
	control_disabled = true
	camera.current = false


func return_free_cam() -> void:
	# TODO alter shot aim based on free camera selection
	arrow_animation.play("show")

	if not keep_projection:
		shot_projection.hide()

	hud.show_hud()
	_free_camera.queue_free()
	_free_camera = null
	control_disabled = false
	_returning_free_camera = false
	camera.current = true


func return_ball() -> void:
	physics_ball.freeze = true
	var tween := get_tree().create_tween()
	(
		tween
		. tween_property(
			physics_ball,
			"global_transform",
			ball_point.global_transform,
			BALL_RETURN_TIME,
		)
		. set_trans(Tween.TRANS_SINE)
	)
	tween.tween_callback(end_shot_track)


func travel_to_ball() -> void:
	physics_ball.freeze = true
	global_position = physics_ball.global_position
	physics_ball.global_transform = ball_point.global_transform


func start_shot_track() -> void:
	if phase == Phase.SHOT:
		_tracking_camera = OrbitalCamera.create(physics_ball)
		_tracking_camera.rotation.y = randf_range(0.0, TAU)
		add_sibling(_tracking_camera)
		_tracking_camera.global_transform = ball_point.global_transform


func end_shot_track() -> void:
	camera.make_current()
	if is_instance_valid(_tracking_camera):
		_tracking_camera.queue_free()
	if phase == Phase.SHOT:
		phase = Phase.FINISHED


## Called immediately before `club` is mutated.
func _on_club_change(new_club_type: Club.Type) -> void:
	var new_club := player.get_club(new_club_type)
	if not new_club:
		# `new_club` will be null if player has no club in the given slot
		# TODO play bonk
		return

	# Hide all arrows
	# TODO animate?
	drive_arrow.hide()
	wedge_arrow.hide()
	iron_arrow.hide()
	putt_arrow.hide()
	physics_ball.iron_ball = false
	hud.club_selector.value = new_club_type
	# TODO club change animation
	character.hold_right(new_club.get_model())
	match new_club_type:
		Club.Type.DRIVER:
			shot_ref = drive_ref
			drive_arrow.show()
		Club.Type.PUTTER:
			shot_ref = putt_ref
			putt_arrow.show()
		Club.Type.WEDGE:
			shot_ref = wedge_ref
			wedge_arrow.show()
		Club.Type.IRON:
			shot_ref = iron_ref
			iron_arrow.show()
			physics_ball.iron_ball = true
		Club.Type.SPECIAL:
			# TODO figure this out
			shot_ref = drive_ref
		_:
			print_debug("Not sure how to equip club type: ", new_club)


## Called immediately before `phase` is mutated.
func _on_phase_change(new_phase: Phase) -> void:
	print_debug("Player ", player.name, ": change to ", Phase.keys()[new_phase])
	match new_phase:
		Phase.AIM:
			hud.set_state_for_player(player)
			hud.show_hud()
			if not arrow.visible:
				arrow_animation.play("show")
			camera.make_current()
			hud.power_bar.hide()
			hud.curve_bar.hide()

			character.reset()
		Phase.POWER_ADJUST:
			hud.curve_bar.hide()

			hud.power_bar.show()
			hud.reset_power_bar()  # Reset if needed
		Phase.CURVE_ADJUST:
			hud.curve_bar.show()
			hud.start_curve_bar()
		Phase.DOWNSWING:
			hud.power_bar.hide()
			hud.curve_bar.hide()
			character.downswing()
			shot_animation.play("swing_delay")  # calls `take_shot`
		Phase.SHOT:
			hud.power_bar.hide()
			hud.curve_bar.hide()

			hud.play_nice_animation()

			if not driving_range:
				shot_animation.play("shoot")
			arrow_animation.play("hide")
			hud.hide_hud()

			take_shot()
		Phase.FINISHED:
			hud.power_bar.hide()
			hud.curve_bar.hide()
			travel_to_ball()
			finished.emit(self)


func _process(delta: float) -> void:
	## Visual updates
	# Rotation
	direction.rotation.y = lerp_angle(
		direction.rotation.y, _target_rotation.y, delta * x_acceleration
	)
	pitch.rotation.x = lerp_angle(pitch.rotation.x, _target_rotation.x, delta * y_acceleration)

	# Arrow lags behind camera control
	arrow_pivot.rotation.y = lerp_angle(
		arrow_pivot.rotation.y, _target_rotation.y, delta * ARROW_ACCELERATION
	)
	# Player lags further behind
	player_pivot.rotation.y = lerp_angle(
		player_pivot.rotation.y, _target_rotation.y, delta * PLAYER_ACCELERATION
	)

	## Input Handling
	if control_disabled:
		if Input.is_action_just_pressed("camera_cancel"):
			if is_instance_valid(_free_camera) and not _returning_free_camera:
				_returning_free_camera = true
				var tween := get_tree().create_tween()
				(
					tween
					. tween_property(
						_free_camera,
						"global_transform",
						camera.global_transform,
						FREE_CAM_RETURN_TIME
					)
					. set_trans(Tween.TRANS_SINE)
				)
				tween.tween_callback(return_free_cam)
		return

	match phase:
		Phase.AIM:
			# Camera zoom
			if Input.is_action_just_pressed("shot_zoom_in"):
				camera_distance = max(camera_distance - 1.0, ZOOM_MIN)
			if Input.is_action_just_pressed("shot_zoom_out"):
				camera_distance = min(camera_distance + 1.0, ZOOM_MAX)

			# Club select
			if Input.is_action_just_pressed("select_driver"):
				club = Club.Type.DRIVER
			if Input.is_action_just_pressed("select_iron"):
				club = Club.Type.IRON
			if Input.is_action_just_pressed("select_wedge"):
				club = Club.Type.WEDGE
			if Input.is_action_just_pressed("select_special"):
				club = Club.Type.SPECIAL
			if Input.is_action_just_pressed("select_putter"):
				club = Club.Type.PUTTER

			# Switch to free cam
			if (
				Input.is_action_just_pressed("camera_back")
				or Input.is_action_just_pressed("camera_forward")
				or Input.is_action_just_pressed("camera_left")
				or Input.is_action_just_pressed("camera_right")
			):
				insert_free_cam()

			# Advance to next phase
			if Input.is_action_just_pressed("shot_accept"):
				phase = Phase.POWER_ADJUST
		Phase.POWER_ADJUST:
			if Input.is_action_just_pressed("shot_accept"):
				# TODO set power gauge parameters if needed
				character.start_upswing()
				hud.start_power_bar()
			if Input.is_action_just_pressed("ui_cancel"):
				hud.reset_power_bar()
				phase = Phase.AIM
			if Input.is_action_just_released("shot_accept") and shot_power > 0:
				hud.stop_power_bar()
				phase = Phase.CURVE_ADJUST
		Phase.CURVE_ADJUST:
			if Input.is_action_just_pressed("ui_cancel"):
				hud.reset_curve_bar()
				phase = Phase.POWER_ADJUST
			if Input.is_action_just_pressed("shot_accept"):
				hud.stop_curve_bar()
				phase = Phase.DOWNSWING
		Phase.SHOT:
			if driving_range and Input.is_action_just_pressed("shot_accept"):
				phase = Phase.AIM
				return_ball()
		Phase.FINISHED:
			if _restart_queued:
				_restart_queued = false
				phase = Phase.AIM


func _on_physics_ball_sleeping_state_changed() -> void:
	if physics_ball.sleeping and phase == Phase.SHOT:
		end_shot_track()


func _on_ball_entered_water() -> void:
	# Should only be possible during SHOT phase, but let's check just to be sure...
	if phase == Phase.SHOT:
		physics_ball.freeze = true
		hud.play_wasted_animation()
		player.life -= WATER_DAMAGE
		ball_return_timer.start(WASTED_BALL_RETURN_DELAY)


func _on_physics_ball_body_entered(_body: Node) -> void:
	print_debug("BONK!")
	if debug_ball_impact:
		get_tree().paused = true
		var snap_point: Node3D = camera
		if _tracking_camera:
			snap_point = _tracking_camera
		_free_camera = FreeCamera.create(snap_point)
		add_sibling(_free_camera)
		control_disabled = true
		camera.current = false


func _on_ball_return_timer_timeout() -> void:
	return_ball()


func _on_hitbox_ball_collision(ball: GameBall) -> void:
	# TODO play animation
	player.life -= ball.base_damage


## Create a new instance for the given player.
static func create(_player: WorldPlayer) -> ShotSetup:
	var instance: ShotSetup = ShotSetup.scene.instantiate()
	instance.player = _player
	return instance
